Cara Menkonversi Antar Basis Bilangan Menggunakan Delphi

Kita menegenal beberapa sistem bilangan. Untuk ilmu komputer, ada dua sistem bilangan yang sering dipakai yaitu Biner dan HexaDecimal. Komputer bekerja dengan sistem bilangan biner yang terdiri angka 0 dan 1. Sedangkan Hexadecimal biasanya dipakai untuk merepresentasikan alamat memori.

Delphi begitu banyak function untuk mengkonversi integer dan decimal ke nilai string. Demikian juga sebaliknya. Lalu apa hubungannya string dengan biner? Untuk merepresentasikan bilangan pada sistem biner dan hexadecimal kita menggunakan string, mis '111' pada sistem biner untuk merepresentasikan angka 7 pada sistem decimal.

1. Konversi Integer Ke HexaDecimal Dan Sebaliknya

Untuk mengkonversi integer ke hexadecimal kita bisa menggunakan function IntToHex. Function ini bisa anda lihat di unit sysutils. Cara penggunaannya silahkan perhatikan baris kode berikut ini :

procedure TfrmKonversiBilangan.btnKonversiIntHexClick(Sender: TObject);
var
  iInteger: Integer;
  sHexa: string;
begin
  if rgKoversi.ItemIndex = 0 then
  begin
    iInteger            := StrToIntDef(Trim(edtInteger.Text), 0);
    edtHexaDecimal.Text := IntToHex(iInteger, 5); 
   // Cara Penggunaan funtion IntToHex
  end else begin
    sHexa               := Trim(edtHexaDecimal.Text);
    edtInteger.Text     := IntToStr(HexToInt(sHexa))
  end;
end;

OK, kita sudah bisa mengkonversi angka integer ke dalam format hexadecimal. Lalu bagaimana caranya mengkonversi hexadecimal ke integer? Delphi tidak mempunyai built function untuk keperluan ini. Jadi kita harus membuat sendiri. Perlu diketahui, penulisan angka hexadecimal dalam delphi harus diawali dengan tanda $ (dollar), mis : $23 aritnya angka 23 dalam format hexadecimal. Dengan fakta ini, kita bisa membuat function untuk mengkonverso Hexadecimal ke integer dengan memanfaatkan function StrToInt. Perhatikan baris kode berikut ini :

function TfrmKonversiBilangan.HexToInt(AHexNum: String): LongInt;
begin
  Result := StrToInt('$' + AHexNum) ;
end;

2. Konversi Integer Ke Biner Dan Sebaliknya

Delphi juga tidak menyediakan built in function untuk mengkonversi angka integer ke decimal. Demikian juga sebaliknya. Jadi sekali lagi kita harus membuat function tersebut sendiri. Perhatikan Baris Kode Berikut :

function TfrmKonversiBilangan.IntToBin(AValue: LongInt; ADigits: integer):
    String;
begin
    Result := StringOfChar ( '0', ADigits ) ;

    while AValue > 0 do
    begin
      if ( AValue and 1 ) = 1 then
      begin
        Result [ ADigits ] := '1';
      end;
      
      dec ( ADigits ) ;
      AValue := AValue shr 1;
    end;
end;

function TfrmKonversiBilangan.BinToInt(AValue: String): LongInt;
var i: Integer;
begin
  Result:=0;

//Hapus angka nol di depan
  while Copy(AValue,1,1) = '0' do
  begin
    AValue := Copy(AValue,2,Length(AValue) - 1);
  end;

//Proses konversi
  for i := Length(AValue) downto 1 do
  begin
   if Copy(AValue,i,1) = '1' then
   begin
     Result := Result + (1 shl (Length(AValue) - i)) ;
   end;
  end;
end;

Kedua function diatas adalah function yang mengkonversi angka integer ke dalam format biner dan sebaliknya. Penggunannya bisa dilihat pada baris dibawah ini

procedure TfrmKonversiBilangan.btnBinKonversiClick(Sender: TObject);
var
  iInteger: Integer;
begin
  if rgBinInt.ItemIndex = 0 then
  begin
    iInteger := StrToIntDef(Trim(edtBinInteger.Text),0);
    edtBinBin.Text      := IntToBin(iInteger, 5)
  end else begin
    edtBinInteger.Text  := IntToStr(BinToInt(Trim(edtBinBin.Text)))
  end;
end;

Mudah bukan? Sourcecode bisa di download di sini