Menambahkan Function Pada Fast Report

Fast report merupakan salah satu reporting tool yang banyak dipakai oleh para developer delphi. Fast Reprt menyediakan built-in function yang sangat memudahkan kita dalam membuat sebuah laporan. Namun adakalanya kita membutuhkan function/procedure yang tidak ada pada built-in function bawaan fast report. Oleh karena itu kita harus menambahkan sendiri.

Untuk menambahkan function pada fast report kita perlu membuat kelas yang diturunkan dari TfsRTTIModule. Lebih jelasnya lihat baris kode berikut ini :

unit uTSFastReportFunction;

interface
uses SysUtils, Classes, fs_iinterpreter, Forms;

type
  TTSFastReportFunction = class(TfsRTTIModule)
  private
    function CallMethod(Instance: TObject; ClassType: TClass; 
                        const MethodName: String; 
                        var Params: Variant): Variant;
  public
    constructor Create(AScript: TfsScript); override;
    function Quot(AString : String): String;

  end;

const
  _Kategori : string = 'My Functions';

Pada baris kode di atas, saya membuat sebuah kelas bernama TTSFastReportFunction yang saya turunkan dari kelas TfsRTTIModule.
Setelah itu kita buat fungsi yang akan kita tambah di fast report. Di sini saya membuat fungsi bernama Quot. Isinya sebagai berikut :

function TTSFastReportFunction.Quot(AString : String): String;
begin
Result := QuotedStr(AString);
end;

Kemudian buat contructor kelas TTSFastReportFunction. Isi dengan baris kode berikut ini :

constructor TTSFastReportFunction.Create;
begin
  inherited Create(AScript);
  with AScript do
  begin
    AddMethod('function Quot(s: String) : String', CallMethod, 
_Kategori,  ' Quoted Str in FR');
end;

end;

Kemudian buat method bernama CallMethod, isikan baris kode berikut ini :

function TTSFastReportFunction.CallMethod(Instance: TObject; 
ClassType: TClass;
    const MethodName: String; var Params: Variant): Variant;
begin
  if MethodName = 'QUOT' then
    Result := Quot(Params[0])
end;

Jangan lupa pada akhir unit pada bagian inizialization tambahkan baris kode berikut :

initialization
  fsRTTIModules.Add(TTSFastReportFunction);

Sebelum menggunakan unit ini, pastikan form yang ada komponen fast reportnya sudah menggunakan unit ini. Anda bisa cek pada bagian Uses. Untuk melihat hasilnya, kita harus menjalan project ini kemudian buka fast report. Anda bisa membuka fast report dengan cara sbb :

try
  frReport1 := TfrxReport.Create(nil);
  frReport1.DesignReport;
finally
  frReport1.Free;
end;

Setelah Fast Report terbuka, function Quot sudah ada pada IDE Fast Report. Lihat gambar di bawah ini :

Sourcecode Bisa didownload di sini