Cara Memasukkan Object Ke Dalam Combobox

Combobox tidak hanya menyediakan fasilitas untuk menampung string saja. Kita bisa menambahkan object ke dalam combobox. Dengan fasilitas ini kita akan mendapat kan banyak manfaatnya. Mis : Kita menyediakan data cabang dalam combobox. Ketika kita akan menyimpan transaksi yang menggunakan data cabang tersebut, tentunya kita membutuhkan ID atau kode dari cabang yng terpilih. Dengan kemampuan bisa menampung object, kita tidak perlu query lagi ke database guna mendapatkan ID/Kode cabang yang terpilih. Kita tinggal ambil object dari cabang yang terpilih, lalu ambil kode atau ID nya.


Untuk memasukkan object kedalam combobox, ikuti langkah - langkah berikut ini :

  TComboObject = class(TComponent)
  private
    FData1: string;
    FData2: string;
    FID: Integer;
  public
    property Data1: string read FData1 write FData1;
    property Data2: string read FData2 write FData2;
    property ID: Integer read FID write FID;
  end;

Kelas TComboObject ini saya turunkan dari TComponent. Nantinya, pada saat create object dari TComboObject, kita set combobox yang akan diisi object sebagai owner dari object tersebut, sehingga ketika comboboxnya di destroy, obect tersebut juga ikut ter destroy 2. Memasukkan Object Ke ComboBox
Untuk mengisinya, saya menambahkan satu buah button dalam form. Pada event OnClick nya saya isi baris kode berikut :

procedure TfrmMain.btnIsiObjectClick(Sender: TObject);
var
  i: Integer;
  lObjectCombo: TComboObject;
begin
  cbbCabang.Items.Clear;
  for i := 1 to 10 do
  begin
    lObjectCombo    := TComboObject.Create(cbbCabang); // ini penting
    lObjectCombo.ID   := i;
    lObjectCombo.Data1 := 'Cabang ' + IntToStr(i); // mis : kita isi nama
    lObjectCombo.Data2 := 'Jalan Ahmad Yani No  ' + IntToStr(i + 10) + ' Surakarta'; // mis : Kita isi alamat;


    cbbCabang.Items.AddObject(lObjectCombo.Data1, lObjectCombo);
  end;

  cbbCabang.ItemIndex := 0; // item index ke 0 yang terpilih pertama kali
end;

3. Menambil Object Dari Combobox
Untuk mengambil object dari cabang terpilih, ikuti langkah langkah berikut :
- Tambahkan dua komponen TEdit, namakan edtNama dan edtAlamat
- Kemudian tambahkan baris kode berikut pada event OnExitnya combobox

procedure TfrmMain.cbbCabangExit(Sender: TObject);
var
  lObjectCombo: TComboObject;
begin
  if cbbCabang.ItemIndex >= 0 then
  begin
    lObjectCombo    := TComboObject(cbbCabang.Items.Objects[cbbCabang.ItemIndex]);
    edtNama.Text    := lObjectCombo.FData1;
    edtAlamat.Text  := lObjectCombo.FData2;
  end;
end;

4. Memasangkan Object Ke Combobox
Untuk memasangkan data kita yang kita dapat (misalkan pada saat proses ubah/edit transaksi) dengan object yang ada di combobox, ikut langkah2 berikut ini :
- Tambahkan sebuah komponen TEdit, namakan edtID
- Tambahkan sebuah button, namakan btnPasang
- Pada event Onclick dari btnPasang, tambahkan baris kode berikut ini :

procedure TfrmMain.btnPasangClick(Sender: TObject);
var
  i: Integer;
  iID: Integer;
  lObjectCombo: TComboObject;
begin
  iID := StrToIntDef(edtID.Text, 0);

  for i := 0 to cbbCabang.Items.Count - 1 do
  begin
    lObjectCombo    := TComboObject(cbbCabang.Items.Objects[i]);
    if iID = lObjectCombo.ID then
    begin
      cbbCabang.ItemIndex := i;
      Exit; // Kalo sdh ketemu lgs keluar
    end;
  end;
end;

Cara menggunakannya , masukkan ID dalam edtID kemudian click btnPasang. Jika ketemu maka cbPasang akan mengarahkan item terpilihnya sesuai dengan ID yang kita masukkan. Mudah bukan?
Sourcecode bisa didownload di sini